Understanding the Japanese Internet with the Internet Yellow Pages

To celebrate APNIC 56 in Kyoto, we’re sharing the successes, challenges, and history of Internet operations in Japan.

Moving to Tokyo was a once-in-a-lifetime experience for me. Discovering another culture brings a lot of surprises, one of them was the ‘Disaster Preparedness Tokyo’ book that came with my new apartment. The level of preparedness for natural disasters in Japan is way beyond anything I have seen in other parts of the world. And I believe this also applies to the Internet in Japan, something I’d like to convey in this article.

Past studies have shown that redundancy and over-provisioning have helped Japanese networks to sustain devastating natural disasters. Unfortunately, access to such a dataset is difficult. Instead, in this article we’ll examine various public Internet topology datasets and show that Japan has a robust Internet topology, although not perfect. We’ll focus on two complementary views on the Japanese Internet. First, the inter-domain routing of main Japanese eyeball and transit networks, and second, the location and naming infrastructure of popular content in Japan. 

This is also a good opportunity to illustrate how one can get insights into the Internet using our latest open source project, the Internet Yellow Pages. The Internet Yellow Pages is a knowledge database that gathers information about Internet resources (for example Autonomous System Numbers (ASNs), IP prefixes, and domain names) and is easily queryable. The examples below are all taken from the Internet Yellow Pages; see the end of the article for the list of all queries used for this article, marked with a reference denoted as: [number].

How is Japan connected to the rest of the Internet?

According to Regional Internet Registry (RIR) data there are 1,257 ASNs registered in Japan [0]. To simplify our analysis we’ll focus only on the main eyeball and transit networks. The Internet Health Report (IHR) provides a ranking based on APNIC’s population estimates that contains both eyeball networks and their main transit, and another ranking based on customer ASNs. For Japan, the top 10 of both rankings boils down to seven Japanese networks and a few Tier 1 networks [1]. 

Main ISPs in Japan

Japan’s incumbent ISP, NTT, has two main domestic ASNs, one for their broadband services (OCN, AS4713) and one for their mobile services (Docomo, AS9605). They also have a large Tier 1 network (GIN, AS2914) located mostly outside of Japan. 

NTT is one of the major ISPs in Japan, but as estimated by APNIC and IHR, the majority of Internet users and ASNs are served by concurrent ISPs including KDDI (AS2516 and JCOM/AS9824), Softbank (AS17676), IIJ (AS2497), and the Research and Education network SINET (AS2907).

To understand how these networks are connected to the Internet, we leverage IHR’s network dependency data. ASN dependency is derived from BGP data and reveals the common provider networks used to reach a certain ASN. For example, NTT OCN (AS4713) is reached mainly from NTT GIN (AS2914). Figure 1 shows the dependencies for the seven Japanese ISPs identified above.

The good news here is that each of the main Japanese ISPs has a diverse connectivity to the rest of the Internet so it is difficult to identify a single point of failure that would disrupt all of them as we can find in some economies. Arguably the most central ASN is NTT GIN (AS2914), which serves 20% of Japanese users and 20% of Japanese ASNs. IIJ (AS2497) is also quite central as about 17% of Japanese ASNs are reached via this network.

Connectivity within Japan?

The connectivity in Japan between main Japanese ISPs is also remarkably diverse. Using PeeringDB data we find that these large Japanese ISPs are all present at several different IXPs [3]. Figure 2 shows that Japan has multiple large IXPs (JPNAP, JPIX, BBIX), which are all located in multiple cities (at least Tokyo and Osaka). This figure also illustrates the many different locations where the main Japanese ISPs can meet and peer with each other and again shows that a single point of failure is difficult to identify.

Popular Japanese domain names

The above views are focused on how Japanese Internet users and transit ASNs are connected to the Internet and to each other. Now we turn our attention to popular Japanese content and where it is hosted. We rely on the Tranco ranking and Cloudflare’s Radar visitor location to make a list of top domain names accessed mainly by Japanese users. To make a short and meaningful list, we focus only on the top 10k domain names in Tranco and keep only the domains that are queried more than 30% of the time from Japan [4]. This gives us 251 domain names with the following top 10 entries:

Domain name	Tranco rank	% DNS query from Japan
yahoo.co.jp	340	72.9%
line.me	356	58.1%
google.co.jp	508	60.8%
rakuten.co.jp	525	69.5%
amazon.co.jp	547	52.2%
fc2.com	678	40.0%
daum.net	772	35.3%
ameblo.jp	833	62.4%
nicovideo.jp	991	80.7%
livedoor.jp	1028	82.5%

Using RIS/RouteViews BGP data and the OpenINTEL DNS data we retrieve the IP address, prefix, and ASN corresponding to each of these domain names. For example, the graph below shows that yahoo.co.jp (red node) resolves to numerous IP addresses (light blue nodes) that belong to two prefixes (dark blue nodes) originated by two different ASNs (purple nodes) — a great example of redundancy!

Looking at the big picture (Figure 4), with all popular Japanese domain names, three main clusters (Amazon, Cloudflare, and Akamai) are revealed. These three clusters contain half of the popular domain names; the rest are mostly served by domestic ASNs. Although the concentration of popular domains in Amazon is quite important (over a third of the selected popular domain names), this is not too different from what we observe in other economies.

There are several different best practices these domain names should follow to ensure availability. To keep it short and stay in the realm of the DNS, we retrieve the authoritative name servers for these domain names and check if they have name servers hosted in different ASNs. Similar to a recent e-gov study published on the APNIC Blog, we found that the majority of domain names rely on a single DNS provider (usually Amazon or Cloudflare). Out of the 249 popular domain names we could get name servers details from, only 46 have name servers hosted in 2 or more ASNs [7]. A good example of DNS redundancy is dmm.com, which has authoritative name servers hosted in Akamai (AS21342), IIJ (AS2497), and their own AS (AS23620).

Wrapping up

I hope this gives a better idea of what the Internet in Japan looks like and a glance at what is possible with our new tool, the Internet Yellow Pages. All the results above are taken directly from The Internet Yellow Pages website; you can reproduce these results by copying the Cypher queries below.

Last but not least, this work wouldn’t have been possible without the data being made available by all the wonderful projects cited in the article — many thanks to them!

Internet Yellow Pages queries

Go to the Internet Yellow Pages website, connect to the database (no login and password are required), and copy/paste the queries there. To obtain the same graphs you should disable the ‘connect result nodes’ option and increase the ‘initial node display’ value in the settings.

[0] Number of ASes registered in Japan:
	MATCH (a:AS)-[:COUNTRY {reference_org:'NRO'}]-(:Country {country_code:'JP'}) 
	RETURN COUNT(DISTINCT a)

[1] Main ASes in Japan:
	MATCH (a)-[:COUNTRY {reference_org:'RIPE NCC'}]-(:Country {country_code:'JP'})
	MATCH (a:AS)-[ra:RANK {reference_name:"ihr.country_dependency"}]->(r:Ranking)--(:Country {country_code:'JP'})
	WHERE ra.rank < 10
	OPTIONAL MATCH (a)-[:NAME {reference_org:"BGP.Tools"}]-(n:Name)
	RETURN DISTINCT a.asn as ASN, n.name AS AS_Name, COLLECT(r.name) as Rankings 
	ORDER BY a.asn

[2] Dependencies for main ASes in Japan:
	// Select top ASes
	MATCH (a)-[:COUNTRY {reference_org:'RIPE NCC'}]-(:Country {country_code:'JP'})
	MATCH (a:AS)-[ra:RANK {reference_name:"ihr.country_dependency"}]->(:Ranking)
	WHERE ra.rank < 10
	// Find their direct dependencies
	OPTIONAL MATCH (a)-[p:PEERS_WITH]-(b), (a)-[d:DEPENDS_ON]->(b)
	WHERE p.rel = 1 AND d.hege > 0.03 AND a<>b
	RETURN a, d, b

[3] IXP membership for main ASes in Japan:
	// Select top ASNs
	MATCH (a)-[:COUNTRY {reference_org:'RIPE NCC'}]-(:Country {country_code:'JP'})
	MATCH (a:AS)-[ra:RANK {reference_name:"ihr.country_dependency"}]->(:Ranking)
	WHERE ra.rank <= 10
	// Find IXP membership
	OPTIONAL MATCH (a)-[m:MEMBER_OF]-(ix:IXP)-[:COUNTRY]-(:Country {country_code:'JP'})
	RETURN a, m, ix

[4] Most popular Japanese domain names:
	MATCH (:Ranking {name: 'Tranco top 1M'})-[ra:RANK]-(dn:DomainName)-[q:QUERIED_FROM]-(c:Country)
	WHERE q.value > 30 AND c.country_code = 'JP'
	RETURN dn.name as domain_name, ra.rank as rank, q.value as per_query_JP
	ORDER BY rank

[5] IP addresses, prefixes, and ASNs related to yahoo.co.jp:
	MATCH p = (dn:DomainName)-[:RESOLVES_TO]-(:IP)-[:PART_OF]-(:Prefix)-[:ORIGINATE {reference_org:'BGPKIT'}]-(a:AS)
	WHERE dn.name = 'yahoo.co.jp'
	RETURN p

[6] Hosts of most popular Japanese domain names:
	MATCH (:Ranking {name: 'Tranco top 1M'})-[ra:RANK]-(dn:DomainName)-[q:QUERIED_FROM]-(c:Country)
	WHERE q.value > 30 AND c.country_code = 'JP' AND ra.rank < 10000
	MATCH (dn:DomainName)-[r:RESOLVES_TO]-(ip:IP)-[p:PART_OF]-(pfx:Prefix)-[o:ORIGINATE]-(net:AS)
	RETURN dn, ip, pfx, net, r, p, o


[7] Number of ASes hosting authoritative name servers per domain:
	MATCH (:Ranking {name: 'Tranco top 1M'})-[ra:RANK]-(dn:DomainName)-[q:QUERIED_FROM]-(c:Country)
	WHERE q.value > 30 AND c.country_code = 'JP' AND ra.rank < 10000
	MATCH (dn:DomainName)-[:MANAGED_BY]-(:AuthoritativeNameServer)-[:RESOLVES_TO]-(:IP)-[:PART_OF]-(:Prefix)-[:ORIGINATE {reference_org:'BGPKIT'}]-(a:AS) 
	RETURN dn.name, count(DISTINCT a) AS nb_asn, COLLECT(distinct a.asn) ORDER BY nb_asn DESC


[8] Authoritative DNS name servers and their originating AS for dmm.com:
	MATCH p = (dn:DomainName)-[:MANAGED_BY]-(:AuthoritativeNameServer)-[:RESOLVES_TO]-(:IP)-[:PART_OF]-(:Prefix)-[:ORIGINATE {reference_org:'BGPKIT'}]-(a:AS)
	WHERE dn.name = 'dmm.com'
	RETURN p

Romain Fontugne is the Deputy Director of IIJ Research Lab, Japan, who focuses on Internet measurements, traffic analysis, and network security.

Rate this article

---

The views expressed by the authors of this blog are their own and do not necessarily reflect the views of APNIC. Please note a Code of Conduct applies to this blog.